LlCastRay/ja

/ja

/LSL

CastRay/ja

llCastRay

要約

関数: list llCastRay( vector start, vector end, list options );

?	関数ID
	遅延
	エネルギー

関数は、指定された開始位置 start から終了位置 end までの線分を投射し、物体のデータを取得します。
ヒットがあった場合、成功したヒットごとにキー (uuid) と位置 (position) の 2 つの必須の値を含むストライド値のリストが返され、最後に追加の整数の status_code が含まれます。ストライドは、オプションで link_number と normal を含むことができます（詳細はRC_DATA_FLAGSを参照）。status_code が負であればエラーコードであり、それ以外の場合はヒット数（およびストライド数）です。を list で返します。

• vector	start	–	starting location
• vector	end	–	ending location
• list	options	–	can consists of any number of option flags and their parameters.

例（デフォルトオプションの成功したレイキャスト）:

[key object_uuid, vector hit_position, integer status_code]

エラーまたは何もヒットしなかった場合の例:

[integer status_code]

仕様

status_code

status_code は、ストライドリストの末尾に追加される数値で、レイキャストに関する追加情報を提供します。

レイキャストが成功した場合、status_code は0以上になり、ヒット数を示します。

レイキャストが失敗した場合（現時点ではシミュレータのパフォーマンスが低い場合のみ）、status_code は負の値になります。シミュレータ全体の物理時間が高すぎてレイキャストを実行できない場合、RCERR_SIM_PERF_LOW がステータスコードとして使用されます。アイデアは、数フレーム後に再試行する必要があることを知らせることです。

status_code error codes and their meanings.

Status Code	V	Description
RCERR_UNKNOWN	未指定の理由でレイキャストが失敗しました。バグレポートを提出してください。
RCERR_SIM_PERF_LOW	シミュレータのパフォーマンスが低いため、レイキャストが失敗しました。しばらく待ってから再試行してください。可能であれば、シーンの複雑さを低減してください。
RCERR_CAST_TIME_EXCEEDED	パーセルまたはエージェントがレイキャストに許可された最大時間を超過したため、レイキャストが失敗しました。このリソースプールは常に補充されるため、数フレーム待ってから再試行すると成功する可能性があります。

RCERR_CAST_TIME_EXCEEDED

注意: SCR-199 によれば、プールはメイングリッドから削除されたため、このリターンコードは現れないはずです。

効率的なレイキャストのためのヒント:

• 返される最大ヒット数をできるだけ小さく保つ
• 制御可能な因子のRC_REJECT_TYPESをできるだけ設定する（これはおそらく最も影響が大きいでしょう）。たとえば、レイに沿って最も近いエージェントの位置のみを知りたい場合は、RC_REJECT_LAND | RC_REJECT_PHYSICAL | RC_REJECT_NONPHYSICAL を使用します。
• 可能な限り、プリムの山を通過したり、凹凸のある物理オブジェクトに対してレイキャストを避けるようにします（カット、中空、ねじれなどがあるもの、および分解がなく物理型が「prim」のメッシュオブジェクトなど）。明らかにこれを常に避けることはできませんので、一部のキャストは他のものよりもかなり長くかかるかもしれません。RCERR_CAST_TIME_EXCEEDED を適切に処理する堅牢なスクリプトを使用して、呼び出しの直後に短時間スリープし、再試行する前に数フレーム待つように計画します。

options parameter

options フラグとそのパラメータ

フラグ	V	パラメータ	デフォルト値	説明
[ RC_REJECT_TYPES ]	0	[ integer filter ]	[ 0 ]	特定の種類のオブジェクト（およびアバター）を無視するためのマスク。
[ RC_DATA_FLAGS ]	2	[ integer flags ]	[ 0 ]	RC_DATA_FLAGS セクションで説明されています。
[ RC_MAX_HITS ]	3	[ integer max_hits ]	[ 1 ]	返す最大ヒット数。最大値は 256。パフォーマンスの問題を避けるため、小さく保つことが推奨されます。
[ RC_DETECT_PHANTOM ]	1	[ integer detect_phantom ]	[ FALSE ]	TRUE（または非ゼロ）に設定すると、ファントムおよびボリューム検出オブジェクトが検出されます。ファントムオブジェクトだけまたはボリューム検出オブジェクトだけを検出することはできません。TRUEに設定すると、RC_REJECT_NONPHYSICALとRC_REJECT_PHYSICALがRC_REJECT_TYPESで設定されていても、常にファントムおよびボリューム検出オブジェクトが検出されます。

RC_REJECT_TYPES

filter is a bitwise-or combination of the following constants: RC_REJECT_AGENTS, RC_REJECT_PHYSICAL, RC_REJECT_NONPHYSICAL, and RC_REJECT_LAND.

RC_REJECT_TYPES and their meanings.

Reject Type	V	Description
RC_REJECT_AGENTS	アバターは検出されません。
RC_REJECT_PHYSICAL	Physical オブジェクトは検出されません。
RC_REJECT_NONPHYSICAL	上記フラグの反対です。物理がないオブジェクトは検出されません。ファントムオブジェクトについてはRC_DETECT_PHANTOMを参照してください。
RC_REJECT_LAND	ランドは検出されません。これは実際のgroundにのみ言及します。

If you reject everything, a script runtime error will be generated (as it makes no sense to do this). Using 0 as the filter value will accept all types (default).

Also note that seated agents are treated like unseated agents. As in, you either get seated and unseated agents in your results, or you use RC_REJECT_AGENTS and get neither.

RC_DATA_FLAGS

flags is a bitwise-or combination of: RC_GET_NORMAL, RC_GET_ROOT_KEY, and RC_GET_LINK_NUM.

RC_DATA_FLAGS and their meanings.

Data Flag	V	Description
RC_GET_NORMAL	ストライドにはヒットした表面の法線が含まれます。
RC_GET_ROOT_KEY	ヒットしたuuidは、子の代わりにオブジェクトのルートに置き換えられます。
RC_GET_LINK_NUM	ストライドにはヒットしたリンク番号が含まれます。

警告

• flags の値によって（RC_DATA_FLAGSを介して提供される）、ストライド内の値の数とタイプが異なります。詳細はRC_DATA_FLAGSを参照してください。
• llGetRot/ja はビューアがしきい値以下でアバターの回転を更新しないため、アバターの正確な視覚的な回転を返しません（VWR-1331を参照）。マウスルック中のアバターの正確な見ている方向を取得するには、代わりにllGetCameraRot/jaを使用してください。
• llCastRay/ja は物理形状がないプリム（PRIM_PHYSICS_SHAPE_TYPE = PRIM_PHYSICS_SHAPE_NONE）を検出しません。
• llCastRay/ja は、レイがプリムの内部で始まる場合、そのプリムを検出しません。これにより、プリムの位置を安全に開始位置として使用できます。
• llCastRay/ja は、開始位置がプリムの外部にある場合、スクリプトが含まれているプリムを検出できます。

この関数の結果は、「エンドポイントが範囲外の場合には信頼性がない」とされています（オブジェクトのヒット数に関係なく、時折ステータスコード0を返すことがあります）。詳細は[1]を参照してください。

サンプル

integer filter;// default is 0

default
{
    state_entry()
    {
        string ownerName = llKey2Name(llGetOwner());
        llOwnerSay("Hello, " + ownerName + "!");
    }

    touch_start(integer total_number)
    {
        vector start = llGetPos();
        vector end = start - <0.0, -25.0, 0.0>;

        if ( filter > 8 )
            filter = 0;

        llOwnerSay("Filter " + (string)filter);

        list results = llCastRay(start, end, [RC_REJECT_TYPES, filter, RC_MAX_HITS, 4] );

        integer hitNum = 0;
        // Handle error conditions here by checking llList2Integer(results, -1) >= 0
        while (hitNum < llList2Integer(results, -1))
        {
            // Stride is 2 because we didn't request normals or link numbers
            key uuid = llList2Key(results, 2*hitNum);

            string name = "Land"; // if (uuid == NULL_KEY)

            if (uuid != NULL_KEY)
                name = llKey2Name(uuid);

            llOwnerSay("Hit " + name + ".");

            ++hitNum;
        }

        ++filter;
    }
}

// Fire a weapon at a target, report a hit

integer gTargetChan = -9934917;

default
{
    attach(key id)
    {
        if (id != NULL_KEY)
        { 
            llRequestPermissions(id,PERMISSION_TAKE_CONTROLS|PERMISSION_TRACK_CAMERA);
        }
    }

    run_time_permissions (integer perm)
    {
        if (perm & PERMISSION_TAKE_CONTROLS|PERMISSION_TRACK_CAMERA) 
        {
            llTakeControls(CONTROL_LBUTTON|CONTROL_ML_LBUTTON,TRUE,FALSE);
        }
    }

    control (key id, integer level, integer edge)
    {
        // User must be in mouselook to aim the weapon
        if (level & edge & CONTROL_LBUTTON)
        {
            llSay(0,"You must be in Mouselook to shoot.  Type \"CTRL + M\" or type \"Esc\" and scroll your mouse wheel forward to enter Mouselook.");
        }
        // User IS in mouselook        
        if (level & edge & CONTROL_ML_LBUTTON)
        {
            vector start = llGetCameraPos();
            // Detect only a non-physical, non-phantom object. Report its root prim's UUID.
            list results = llCastRay(start, start+<60.0,0.0,0.0>*llGetCameraRot(),[RC_REJECT_TYPES,RC_REJECT_PHYSICAL|RC_REJECT_AGENTS|RC_REJECT_LAND,RC_DETECT_PHANTOM,FALSE,RC_DATA_FLAGS,RC_GET_ROOT_KEY,RC_MAX_HITS,1]);
            llTriggerSound(llGetInventoryName(INVENTORY_SOUND,0),1.0);
            llSleep(0.03);
            key target = llList2Key(results,0);
            // Tell target that it has been hit. 
            llRegionSayTo(target,gTargetChan,"HIT");
            // Target, scripted to listen on gTargetChan, can explode, change color, fall over .....
        }
    }            
}

注意点

Use llDumpList2String to see what the output looks like when you try a new set of flags.

To quickly get the status code use llList2Integer(result, -1).

使い方のアイデア:

• 武器 - レイキャストは、プロジェクタイル武器をシミュレートするためのゲーム開発で伝統的に使用されるツールです。これは、プリムをレザリングして武器から発射するよりもはるかに効率的です。
• AIオブジェクト - アバターや他のオブジェクトの視線検出、または自分自身を中心にレイを追跡して環境を移動するためのツールとして使用されます。例えば、現在の床の表面の高さと角度（法線）を判定するために、直接下向きにレイをキャストして、非物理的なオブジェクトの移動に役立ちます。
• インテリジェントなオブジェクト配置 - 静的なオブジェクトはシーンに配置されますが、環境に合わせて自己調整します。例えば、高い位置にレザリングされたオブジェクトは、その高さを床のレベルに調整したり、低い位置に配置されたコンピュータコンソールは、立ってではなく膝をついて使用するようにアバターに影響を与えたりします。
• 環境分析 - 周囲のエリアの制限を判定するために使用できます。例えば、オブジェクトが閉じられた部屋内に配置されているかどうかを判定することができます。頻繁に実行するべきではないテストですが、部屋内に誰もいない場合は効果をオフにするためにオブジェクトによって使用されたりします。家具やオブジェクトを自動調整して壁、床、天井にスナップすることがあります。

特記事項

経緯

• Date of Release 23/09/2011
• SCR-199 - fixed - The throttle was too low and thus rendered the function not as useful as it could be.

All Issues

~ Search JIRA for related Issues

VWR-1331

Improve accuracy of avatar's visible rotation

Signature
function list llCastRay( vector start, vector end, list options );

この翻訳は 原文 と比べて古いですか？間違いがありますか？読みにくいですか？みんなで 修正 していきましょう！ (手順はこちら)

この項目はあなたにとって参考にならない項目ですか？もしかしたらLSL Wikiの関連した項目が参考になるかもしれません。