LlGetLinkKey

Template:Needs Translation/LSL/de Template:Needs Translation/LSL/es Template:Needs Translation/LSL/el Template:Needs Translation/LSL/he Template:Needs Translation/LSL/it Template:Needs Translation/LSL/ko Template:Needs Translation/LSL/nl Template:Needs Translation/LSL/hu Template:Needs Translation/LSL/no Template:Needs Translation/LSL/da Template:Needs Translation/LSL/sv Template:Needs Translation/LSL/tr Template:Needs Translation/LSL/pl Template:Needs Translation/LSL/pt Template:Needs Translation/LSL/th Template:Needs Translation/LSL/uk Template:Needs Translation/LSL/zh-Hans Template:Needs Translation/LSL/zh-Hant

/LSL

llGetLinkKey

Summary

llGetLinkKey

llGetLinkKey

Function: key llGetLinkKey( integer link );

0.0	Forced Delay
10.0	Energy

Returns the key of the linked prim link

• integer

link

–

Link number (0: unlinked, 1: root prim, >1: child prims and seated avatars) or a LINK_* flag

Caveats

• link needs to be either an actual link number or a link constants that equate to a single prim, such as LINK_ROOT and LINK_THIS.
  • LINK_SET, LINK_ALL_CHILDREN and LINK_ALL_OTHERS will not work.

llGetObjectLinkKey

Function: key llGetObjectLinkKey( key object_id, integer link );

0.0	Forced Delay
10.0	Energy

Returns the key of the linked prim link in the linkset identified by object_id

• key	object_id
• integer	link	–	Link number (0: unlinked, 1: root prim, >1: child prims and seated avatars) or a LINK_* flag

Flag Description LINK_ROOT 1 refers to the root prim in a multi-prim linked set[1]

Flag Description LINK_THIS -4 refers to the prim the script is in

Examples

Drag this script on to linked and unlinked prims, with avatars sitting or not, to see how llGetLinkKey relates to llGetKey, llGetLinkNumber, llGetNumberOfPrims, LINK_ROOT, etc.

// Return the name of a link num else the empty string.
string getLinkNumName(integer link)
{
    if (LINK_THIS == link) return "LINK_THIS";
    if (LINK_ALL_CHILDREN == link) return "LINK_ALL_CHILDREN";
    if (LINK_ALL_OTHERS == link) return "LINK_ALL_OTHERS";
    if (LINK_SET == link) return "LINK_SET";
    if (LINK_ROOT == link) return "LINK_ROOT";
    return "";
}

// Say the key of each linked prim.
default
{
    state_entry()
    {
        integer theLink = llGetLinkNumber();
        
        key theLinkKey = llGetKey();
        key owner = llGetOwner();
        key creator = llGetCreator();
        
        // Visit each link num.
        
        integer link;
        integer primmed = llGetNumberOfPrims();
        for (link = -5; link <= (primmed + 5); ++link)
        {
            key linkKey = llGetLinkKey(link);
            
            // Detail the key at the link num.
            
            string line = (string) linkKey; // large constant width
            
            if (linkKey == owner) line += " llGetOwner";
            if (linkKey == creator) line += " llGetCreator";
            if (linkKey == theLinkKey) line += " llGetKey";
            
            // Detail the link num.
            
            line += " @ " + (string) link;
            line += " " + getLinkNumName(link);
            if (link == theLink) line += " llGetLinkNumber";
            if (link == primmed) line += " llGetNumberOfPrims";
            
            // Say the detail if fun.
            
            if (linkKey != NULL_KEY)
            {
                llOwnerSay(line);
            }
        }
        
        // Always count the linked prims.
        
        llOwnerSay((string) primmed + " llGetNumberOfPrims");
        llOwnerSay("OK");
    }
}

Notes

Link Numbers

Each prim that makes up an object has an address, a link number. To access a specific prim in the object, the prim's link number must be known. In addition to prims having link numbers, avatars seated upon the object do as well.

• If an object consists of only one prim, and there are no avatars seated upon it, the (root) prim's link number is zero.
• However, if the object is made up of multiple prims or there is an avatar seated upon the object, the root prim's link number is one.

When an avatar sits on an object, it is added to the end of the link set and will have the largest link number. In addition to this, while an avatar is seated upon an object, the object is unable to link or unlink prims without unseating all avatars first.

Counting Prims & Avatars

There are two functions of interest when trying to find the number of prims and avatars on an object.

• llGetNumberOfPrims() - Returns the number of prims and seated avatars.
• llGetObjectPrimCount(llGetKey()) - Returns only the number of prims in the object but will return zero for attachments.

integer GetPrimCount() { //always returns only the number of prims
    if(llGetAttached())//Is it attached?
        return llGetNumberOfPrims();//returns avatars and prims but attachments can't be sat on.
    return llGetObjectPrimCount(llGetKey());//returns only prims but won't work on attachments.
}

See llGetNumberOfPrims for more about counting prims and avatars.

Errata

If a script located in a child prim erroneously attempts to access link 0, it will get or set the property of the linkset's root prim. This bug (BUG-5049) is preserved for broken legacy scripts.

See Also

Functions

•	llGetLinkNumber	–	Returns the link number of the prim the script is in.
•	llGetKey
•	llGetLinkName

Deep Notes

Footnotes

1. ^ LINK_ROOT does not work on single prim objects. Unless there is an avatar sitting on the object.

Signature
function key llGetLinkKey( integer link ); function key llGetObjectLinkKey( key object_id, integer link );