llSetLinkAlpha

Template:Needs Translation/LSL/es Template:Needs Translation/LSL/el Template:Needs Translation/LSL/he Template:Needs Translation/LSL/it Template:Needs Translation/LSL/ko Template:Needs Translation/LSL/nl Template:Needs Translation/LSL/hu Template:Needs Translation/LSL/no Template:Needs Translation/LSL/da Template:Needs Translation/LSL/sv Template:Needs Translation/LSL/tr Template:Needs Translation/LSL/pl Template:Needs Translation/LSL/pt Template:Needs Translation/LSL/th Template:Needs Translation/LSL/uk Template:Needs Translation/LSL/zh-Hans Template:Needs Translation/LSL/zh-Hant

/LSL

SetLinkAlpha

llSetLinkAlpha

Summary

Function: llSetLinkAlpha( integer linknumber, float alpha, integer face );

0.0	Forced Delay
10.0	Energy

If a prim exists in the link set at linknumber, set alpha on face of that prim.

• integer	linknumber	–	Link number (0: unlinked, 1: root prim, >1: child prims and seated avatars) or a LINK_* flag
• float	alpha	–	from 0.0 (clear) to 1.0 (solid) (0.0 <= alpha <= 1.0)
• integer	face	–	face number or ALL_SIDES

If face is ALL_SIDES then the function works on all sides.

Flag Description LINK_ROOT 1 refers to the root prim in a multi-prim linked set[1] LINK_SET -1 refers to all prims LINK_ALL_OTHERS -2 refers to all other prims

Flag Description LINK_ALL_CHILDREN -3 refers to all children, (everything but the root) LINK_THIS -4 refers to the prim the script is in

Caveats

• The function silently fails if its face value indicates a face that does not exist.

Examples

Make the entire object disappear for 5 seconds <lsl> default {

   touch_start(integer detected)
   {
       llSetLinkAlpha(LINK_SET, 0.0, ALL_SIDES);
       llSetTimerEvent(5.0);
   }
   timer()
   {
       llSetLinkAlpha(LINK_SET, 1.0, ALL_SIDES);
       llSetTimerEvent(0.0);
   }

} </lsl> Makes selected prims in a linkset become transparent or visible on chat command. Give each prim a unique name. <lsl> list PrimList; default {

    state_entry()
    {
         integer NumLink = llGetNumberOfPrims();
         llListen(37,"","","");
         integer i;
         for (i=1;i<=NumLink;++i)
         {
              PrimList += llGetLinkName(i); 
         }
    }
    listen( integer channel, string name, key id, string msg)
    {
         list temp = llCSV2List(msg);
         integer len = llGetListLength (temp);
         string Alpha = llToUpper(llList2String(temp,0));
         integer i;
         for (i=1;i<len;++i)
         {
               string ThisPrim = llStringTrim(llList2String(temp,i),STRING_TRIM);
               integer idx = llListFindList(PrimList, [ThisPrim]);
               if (~idx)
              {
                   if (Alpha == "SHOW")
                   {
                        llSetLinkAlpha(idx+1, 1.0, ALL_SIDES); //Ex:  SHOW,plate,spoon, napkin  <---- makes named prims visible
                   }
                   else if (Alpha == "HIDE")
                   {
                        llSetLinkAlpha(idx+1,0.0, ALL_SIDES); //Ex:  HIDE, butter knife, glass, fork, spoon  <--- makes named prims transparent
                   }
              }
              else if (llToUpper(ThisPrim) == "ALL")
              {
                   if (Alpha == "SHOW")
                   {
                        llSetLinkAlpha(LINK_SET, 1.0, ALL_SIDES);  //Ex:  SHOW, ALL  <--- makes the entire linkset visible
                   }
                   else if (Alpha == "HIDE")
                   { 
                        llSetLinkAlpha(LINK_SET, 0.0, ALL_SIDES);  //Ex:  HIDE, All  <--- makes the entire linkset transparent
                   }
              }
                  
         }
    }
    changed (integer change)
    {
         if (change & CHANGED_LINK)
         {
              llResetScript();
         }
    }

}</lsl>

Notes

Link Numbers

Each prim that makes up an object has an address, a link number. To access a specific prim in the object, the prim's link number must be known. In addition to prims having link numbers, avatars seated upon the object do as well.

• If an object consists of only one prim, and there are no avatars seated upon it, the (root) prim's link number is zero.
• However, if the object is made up of multiple prims or there is an avatar seated upon the object, the root prim's link number is one.

When an avatar sits on an object, it is added to the end of the link set and will have the largest link number. In addition to this, while an avatar is seated upon an object, the object is unable to link or unlink prims without unseating all avatars first.

Counting Prims & Avatars

There are two functions of interest when trying to find the number of prims and avatars on an object.

• llGetNumberOfPrims() - Returns the number of prims and seated avatars.
• llGetObjectPrimCount(llGetKey()) - Returns only the number of prims in the object but will return zero for attachments.

integer GetPrimCount() { //always returns only the number of prims
    if(llGetAttached())//Is it attached?
        return llGetNumberOfPrims();//returns avatars and prims but attachments can't be sat on.
    return llGetObjectPrimCount(llGetKey());//returns only prims but won't work on attachments.
}

See llGetNumberOfPrims for more about counting prims and avatars.

Errata

If a script located in a child prim erroneously attempts to access link 0, it will get or set the property of the linkset's root prim. This bug (BUG-5049) is preserved for broken legacy scripts.

See Also

Events

•

changed

–

CHANGED_COLOR

Functions

•	llGetLinkNumber	–	Returns the link number of the prim the script is in.
•	llGetAlpha	–	Gets the prim's alpha
•	llSetAlpha	–	Sets the prim's alpha
•	llGetColor	–	Gets the prim's color
•	llSetColor	–	Sets the prim's color
•	llSetLinkColor
•	llSetLinkTexture
•	llSetLinkPrimitiveParams

Articles

•

Translucent Color

Deep Notes

Footnotes

1. ^ LINK_ROOT does not work on single prim objects. Unless there is an avatar sitting on the object.

Signature
function void llSetLinkAlpha( integer linknumber, float alpha, integer face );