llTeleportAgent

Template:Needs Translation/LSL/de Template:Needs Translation/LSL/es Template:Needs Translation/LSL/el Template:Needs Translation/LSL/fr Template:Needs Translation/LSL/he Template:Needs Translation/LSL/it Template:Needs Translation/LSL/ko Template:Needs Translation/LSL/nl Template:Needs Translation/LSL/hu Template:Needs Translation/LSL/no Template:Needs Translation/LSL/da Template:Needs Translation/LSL/sv Template:Needs Translation/LSL/tr Template:Needs Translation/LSL/pl Template:Needs Translation/LSL/pt Template:Needs Translation/LSL/ru Template:Needs Translation/LSL/th Template:Needs Translation/LSL/uk Template:Needs Translation/LSL/zh-Hans Template:Needs Translation/LSL/zh-Hant

/LSL

TeleportAgent

llTeleportAgent

Summary

Function: llTeleportAgent( key avatar, string landmark, vector position, vector look_at );

	Forced Delay
	Energy

Requests a teleport of avatar to a landmark stored in the object's inventory. If no landmark is provided (an empty string), the avatar is teleported to the location position in the current region. In either case, the avatar is turned to face the direction given by look_at.

• key	avatar	–	avatar UUID that is in the same region (the avatar to teleport, must be the owner)
• string	landmark	–	a landmark in the inventory of the prim this script is in or an empty string (for teleporting within the same region)
• vector	position	–	The position within the local region to teleport the avatar to if no landmark was provided.
• vector	look_at	–	If landmark is provided, a direction to face (same as in llTeleportAgentGlobalCoords). If landmark is not provided, the position within the region that the avatar should be turned to face upon arrival.

To run this function the script must request the PERMISSION_TELEPORT permission with llRequestPermissions and it must be granted by avatar.

Caveats

• If landmark is not an empty string and...
  • landmark is missing from the prim's inventory or it is not a landmark then an error is shouted on DEBUG_CHANNEL.

Permissions

Do not depend upon the auto-grant status of permissions. Always use the run_time_permissions event. If the script lacks the permission PERMISSION_TELEPORT, the script will shout an error on DEBUG_CHANNEL and the operation fails (but the script continues to run). If PERMISSION_TELEPORT is granted by anyone other than avatar, then when the function is called an error will be shouted on DEBUG_CHANNEL. Once the PERMISSION_TELEPORT permission is granted there is no way to revoke it except from inside the script (for example, with a new llRequestPermissions call) or the script is reset or deleted.

• This function can only teleport the owner of the object (unless part of an Experience).
• Teleports are throttled
• This function cannot be used in a script in an object attached using llAttachToAvatarTemp.
• Sitting avatars cannot be teleported using this function. You must llUnSit them first.
• This function does not override a parcel's teleport settings, i.e. if the parcel has a landing zone enabled the agent will be teleported there.
• If the script is part of an experience that the avatar has granted permission, then this function may teleport them without being the owner and it will override parcel teleport routing. See the example below.

Examples

Without a landmark in the object's inventory

key  teleportee;

default
{
    state_entry()
    {
        llSay(0, "Touch to teleport");
    }

    touch_start(integer total_num)
    {
        teleportee = llDetectedKey(0);
        llRequestPermissions(teleportee, PERMISSION_TELEPORT);
    }
    
    run_time_permissions(integer perm)
    {
        if(PERMISSION_TELEPORT & perm)
        {
            llTeleportAgent(teleportee, "", <13.0, 38.0, 23.5>, <13.0, 12.0, 23.5>);
        }
    }
}

With a landmark in the objects inventory

key  teleportee;

default
{
    state_entry()
    {
        llSay(0, "Touch to teleport");
    }

    touch_start(integer total_num)
    {
        teleportee = llDetectedKey(0);
        llRequestPermissions(teleportee, PERMISSION_TELEPORT);
    }
    
    run_time_permissions(integer perm)
    {
        if(PERMISSION_TELEPORT & perm)
        {
            llTeleportAgent(teleportee, "Experience Tools 1", <0.0, 0.0, 0.0>, <0.0, 0.0, 0.0>);
        }
    }
}

How to use this function in an Experience

// A SIMPLE SCRIPT that implements an Experience based teleport.
// Compile with the "Use Experience" box cnecked and an experience key you own selected.
// The prim containing this script must contain a landmark named "Landmark" in its contents
//
// If the person touching this box has not previously accepted an invitation to your experience,
// that person will be offered that opportunity when this prim is touched, and if the invitations
// is accepted, will be immediately teleported to the target of the landmark.
//
// If the toucher has previously accepted an invitation, the person will be immediately teleported
// with no interruption.
//
// The script has no safety features, e.g., will simply fail if the prim contains no landmark.
//
// Thanks to Rolig Loon for her help in figuring out how to do this
// See https://community.secondlife.com/t5/English-Knowledge-Base/Experiences-in-Second-Life/ta-p/2744686
// to read what the Lindens think is an adequate explanation of all this.


default
{
    touch_start(integer n)
    {
        llRequestExperiencePermissions(llDetectedKey(0), "");
    }
    
    experience_permissions(key av)
    {
        llTeleportAgent(av, "Landmark", ZERO_VECTOR, ZERO_VECTOR);
    }
 
}

See Also

Events

•

run_time_permissions

–

Permission receiving event

Functions

•	llGetPermissions	–	Get the permissions granted
•	llGetPermissionsKey	–	Get the agent who granted permissions
•	llRequestPermissions	–	Request permissions
•	llTeleportAgentGlobalCoords	–	Teleports an agent to a global position.

Articles

•

Script permissions

Deep Notes

History

Date of Release 24/07/2012

Signature
function void llTeleportAgent( key avatar, string landmark, vector position, vector look_at );