LlMessageLinked

The purpose of this function is to allow scripts in the same object to communicate. It triggers a link_message event with the same parameters num, str, and id in all scripts in the prim(s) described by linknum.

• integer	linknum	–	Link number or a LINK_* flag, controls which prim(s) receive the link_message.
• integer	num	–	Value of the second parameter of the resulting link_message event.
• string	str	–	Value of the third parameter of the resulting link_message event.
• key	id	–	Value of the fourth parameter of the resulting link_message event.

You can use id as a second string field^[1]. The sizes of str and id are only limited by available script memory.

• A script can hear its own linked messages if linknum targets the prim it is in^[2]. This creates the possibility of an infinite loop (a bad thing); be very careful about how messages are handled and passed along.
• Messages sent via llMessageLinked to a script that is sleeping, delayed, or lagged, are queued until the end of the delay. The event queue can hold 64 events.
  • If an event is received and the queue is full the event is silently dropped.
  • Avoid sending link_messages to large numbers of scripts simultaneously as it can cause lag spike. This most often happens when using the multi-prim LINK_* flags and can cause script execution to slow or halts.
  • Avoid sending link_messages to a target faster then they can be handled. Doing so risks filling the event queue and subsequent messages being silently discarded.
• When a script state changes, all pending events are deleted, including queued link_messages.
• If link_num is an invalid link number then the function silently fails.
• If str & id exceed the available memory of a script that catches the resulting link_message event, that script will crash with a Stack-Heap Collision.

Search JIRA for related Bugs

default{ // assumptions  // object name: LSLWiki // script name: _lslwiki
    state_entry() {
        llMessageLinked(LINK_THIS, 0, llGetScriptName(), "");
    }
 
    link_message(integer sender_num, integer num, string msg, key id) {
        llOwnerSay(msg);
        // the owner of object LSLWiki will hear
        // LSLWiki:_lslwiki
    }    
}

default
{ // Quick and dirty debugging link_messages
    link_message(integer sender_num, integer num, string msg, key id) {
        llSay(DEBUG_CHANNEL, llList2CSV([sender_num, num, msg, id]));
    }
}

// This is just an example script, you shouldn't handle link message within single script this way.
 
default{ // To propagate an unlimted number of arguments of any type.
	 // Presumed, the separator string isn't used in any source string!
    state_entry() {
        list my_list = [1, 2.0, "a string", <1, 2, 3>, <1, 2, 3, 4>, llGetOwner()];  
        string list_parameter = llDumpList2String(my_list, "|");	// Convert the list to a string
        llMessageLinked(LINK_THIS, 0, list_parameter, "")
    }
 
    link_message(integer sender_num, integer num, string list_argument, key id) {
        list re_list = llParseString2List(list_argument, ["|"], []);	// Parse the string back to a list
    }
}

• Using llMessageLinked in a single prim object allows developers to mitigate some LSL limits by breaking up functionality between cooperating scripts and synchronizing actions. When you do this, be extremely careful not to create infinite loops as mentioned above.
• Some users have noted occasional failures of linked messages when sending a message to a large number of receiving scripts in different prims using LINK_SET, LINK_ALL_OTHERS, & LINK_ALL_CHILDREN. If you encounter this problem, a workaround is to place all child prim scripts in a single prim, using targeted functions like llSetLinkPrimitiveParams to modify the prim in which the script previously resided. -- Void Singer

Events

•

link_message

Functions

•

llGetLinkNumber

–

Returns the link number of the prim the script is in.

Issues

Search JIRA for related Issues

Footnotes