llNavigateTo

From Second Life Wiki
Jump to navigation Jump to search

Summary

Function: llNavigateTo( vector pos, list options );

Directs an object to travel to a defined position in the region or adjacent regions.

• vector pos position in region coordinates for the character to navigate to.
• list options List of parameters to control the type of pathfinding used.

Adjacent regions can be reached by extending the position vector into the nearby region.

Option Value Parameters Default Description
FORCE_DIRECT_PATH 1 integer boolean ] FALSE ] Makes character navigate in a straight line toward pos. May be set to TRUE or FALSE.

Caveats

  • Must use llCreateCharacter first or the function will fail with a viewer error.
  • Vertical positions specified for any vectors should be chosen to be as close as possible to the actual height of the surface requested. Large difference between the provided vertical position and the actual terrain/object will result in failure of the behavior.
  • If you want to chase an agent or object as per the example below, it's much more elegant and less sim resource intensive to use llPursue instead.
All Issues ~ Search JIRA for related Bugs

Examples

vector last_touched_pos;
key last_touched_key;

default
{
    state_entry()
    {
        llCreateCharacter([CHARACTER_DESIRED_SPEED, 50.0]);
    }

    touch_start(integer total_number)
    {
        last_touched_key = llDetectedKey(0);
        last_touched_pos = llList2Vector(llGetObjectDetails(last_touched_key, [OBJECT_POS]), 0);
        llNavigateTo(last_touched_pos, []);
        llSetTimerEvent(0.2);
    }

    timer()
    {
        vector last_touched_pos_now = llList2Vector(llGetObjectDetails(last_touched_key, [OBJECT_POS]), 0);
        if ( llVecDist(last_touched_pos_now, last_touched_pos) > 1 )
        {
            last_touched_pos = last_touched_pos_now;
            llNavigateTo(last_touched_pos, []);
        }
    }
}

Notes

  • FORCE_DIRECT_PATH can be used to rescue characters that have somehow fallen off the navigable zone as it doesn't use the navmesh.

(Needs verification.)

  • The position vector can be set outside the current region by using extended range region coordinates: e.g., to go to the SE corner of the region to the East of the current one, you could llNavigateTo(<0.0, 512.0, 0.0>, []);

Deep Notes

History

Date of Release 31/07/2012

Search JIRA for related Issues

Signature

function void llNavigateTo( vector pos, list options );