LlTakeControls

Allows for intercepting of keyboard and mouse clicks, specifically those specified by controls, from the agent the script has permissions for.

Requires the PERMISSION_TAKE_CONTROLS permission to run. If accept is FALSE and pass_on is FALSE, then the specified controls behave normally, and all other controls are disabled.
If accept is FALSE and pass_on is TRUE, then all controls behave normally.
If accept is TRUE and pass_on is FALSE, then the specified controls are disabled (but generate control events), and all other controls behave normally.
If accept is TRUE and pass_on is TRUE, then the specified controls generate control events, and all controls behave normally.

• Do not depend upon the auto-grant status of permissions. Always use the run_time_permissions event.
• If the script lacks the permission PERMISSION_TAKE_CONTROLS, the script will shout an error on DEBUG_CHANNEL and the operation fails (but the script continues to run).
• Once the PERMISSION_TAKE_CONTROLS permission is granted, it can be revoked from inside the script (with llReleaseControls or a new llRequestPermissions call), or if the user chooses Release Keys from the viewer. Otherwise, the script will only lose the permission if it is reset or the object derezzed (deleted, detached, or taken).

Important Issues

SVC-3187

[c]

llTakeControls overrides existing controls

default
{
    state_entry()
    {
        llRequestPermissions(llGetOwner(), PERMISSION_TAKE_CONTROLS);
    }
    run_time_permissions(integer perm)
    {
        if(PERMISSION_TAKE_CONTROLS & perm)
        {
            llTakeControls(
                            CONTROL_FWD |
                            CONTROL_BACK |
                            CONTROL_LEFT |
                            CONTROL_RIGHT |
                            CONTROL_ROT_LEFT |
                            CONTROL_ROT_RIGHT |
                            CONTROL_UP |
                            CONTROL_DOWN |
                            CONTROL_LBUTTON |
                            CONTROL_ML_LBUTTON |
                            0, TRUE, TRUE);
        }
    }
    control(key id, integer level, integer edge)
    {
        integer start = level & edge;
        integer end = ~level & edge;
        integer held = level & ~edge;
        integer untouched = ~(level | edge);
        llOwnerSay(llList2CSV([level, edge, start, end, held, untouched]));
    }
}

If a script has taken controls, it and other scripts in the same prim will not be stopped if the Agent enters a No-Script Area. This is done to keep vehicle control alive and AOs functional. This is an intentional feature. These scripts will stop working if they call certain blacklisted functions.

Events

Functions

Articles

Issues

SVC-3187

[c]

llTakeControls overrides existing controls