llSetLinkTexture

Template:Needs Translation/LSL/de Template:Needs Translation/LSL/es Template:Needs Translation/LSL/el Template:Needs Translation/LSL/he Template:Needs Translation/LSL/it Template:Needs Translation/LSL/ko Template:Needs Translation/LSL/nl Template:Needs Translation/LSL/hu Template:Needs Translation/LSL/no Template:Needs Translation/LSL/da Template:Needs Translation/LSL/sv Template:Needs Translation/LSL/tr Template:Needs Translation/LSL/pl Template:Needs Translation/LSL/pt Template:Needs Translation/LSL/th Template:Needs Translation/LSL/uk Template:Needs Translation/LSL/zh-Hans Template:Needs Translation/LSL/zh-Hant

/LSL

SetLinkTexture

llSetLinkTexture

Summary

2/3 Bugs

Function: llSetLinkTexture( integer link, string texture, integer face );

0.2	Forced Delay
10.0	Energy

If a prim exists in the link set at link, set texture on face of that prim.

• integer	link	–	Link number (0: unlinked, 1: root prim, >1: child prims and seated avatars) or a LINK_* flag
• string	texture	–	a texture in the inventory of the prim this script is in or a UUID of a texture
• integer	face	–	face number or ALL_SIDES

If face is ALL_SIDES then the function works on all sides.

Flag Description LINK_ROOT 1 refers to the root prim in a multi-prim linked set[1] LINK_SET -1 refers to all prims LINK_ALL_OTHERS -2 refers to all other prims

Flag Description LINK_ALL_CHILDREN -3 refers to all children, (everything but the root) LINK_THIS -4 refers to the prim the script is in

Caveats

• This function causes the script to sleep for 0.2 seconds.
• If texture is missing from the prim's inventory or not full permissions and it is not a UUID or it is not a texture then an error is shouted on DEBUG_CHANNEL.
• If texture is a UUID then there are no new asset permissions consequences for the object.
  • The resulting object develops no new usage restrictions that might have occurred if the asset had been placed in the prims inventory.
• The function silently fails if its face value indicates a face that does not exist.

Examples

Cover a link set in the texture "bark" (from the library)

default
{
    touch_start(integer detected)
    {
        llSetLinkTexture(LINK_SET, "66bf4030-04f9-a808-43ab-b48b6aeb6456", ALL_SIDES);
    }
}

Useful Snippets

SetLinkTextureFast

This function doesn't have the 0.2 second delay. It's not very fast anyway though, but faster than llSetLinkTexture.

SetLinkTextureFast(integer link, string texture, integer face)
{
    // Obtain the current texture parameters and replace the texture only.
    // If we are going to apply the texture to ALL_SIDES, we need
    // to adjust the returned parameters in a loop, so that each face
    // keeps its current repeats, offsets and rotation.
    list Params = llGetLinkPrimitiveParams(link, [PRIM_TEXTURE, face]);
    integer idx;
    face *= face > 0; // Make it zero if it was ALL_SIDES
    // This part is tricky. The list returned by llGLPP has a 4 element stride
    // (texture, repeats, offsets, angle). But as we modify it, we add two
    // elements to each, so the completed part of the list has 6 elements per
    // stride.
    integer NumSides = llGetListLength(Params) / 4; // At this point, 4 elements per stride
    for (idx = 0; idx < NumSides; ++idx)
    {
        // The part we've completed has 6 elements per stride, thus the *6.
        Params = llListReplaceList(Params, [PRIM_TEXTURE, face++, texture], idx*6, idx*6);
    }
    llSetLinkPrimitiveParamsFast(link, Params);
}

Notes

Link Numbers

Each prim that makes up an object has an address, a link number. To access a specific prim in the object, the prim's link number must be known. In addition to prims having link numbers, avatars seated upon the object do as well.

• If an object consists of only one prim, and there are no avatars seated upon it, the (root) prim's link number is zero.
• However, if the object is made up of multiple prims or there is an avatar seated upon the object, the root prim's link number is one.

When an avatar sits on an object, it is added to the end of the link set and will have the largest link number. In addition to this, while an avatar is seated upon an object, the object is unable to link or unlink prims without unseating all avatars first.

Counting Prims & Avatars

There are two functions of interest when trying to find the number of prims and avatars on an object.

• llGetNumberOfPrims() - Returns the number of prims and seated avatars.
• llGetObjectPrimCount(llGetKey()) - Returns only the number of prims in the object but will return zero for attachments.

integer GetPrimCount() { //always returns only the number of prims
    if(llGetAttached())//Is it attached?
        return llGetNumberOfPrims();//returns avatars and prims but attachments can't be sat on.
    return llGetObjectPrimCount(llGetKey());//returns only prims but won't work on attachments.
}

See llGetNumberOfPrims for more about counting prims and avatars.

Errata

If a script located in a child prim erroneously attempts to access link 0, it will get or set the property of the linkset's root prim. This bug (BUG-5049) is preserved for broken legacy scripts.

See Also

Functions

•	llGetLinkNumber	–	Returns the link number of the prim the script is in.
•	llGetLinkNumberOfSides	–	Returns the number of faces of the linked prim.
•	llSetLinkAlpha
•	llSetLinkColor
•	llSetLinkPrimitiveParams

Articles

•

Internal Textures

Deep Notes

History

• Date of release 21-02-2007

Footnotes

1. ^ LINK_ROOT does not work on single prim objects. Unless there is an avatar sitting on the object.

Signature
function void llSetLinkTexture( integer link, string texture, integer face );