llTransferLindenDollars

Template:Needs Translation/LSL/de Template:Needs Translation/LSL/es Template:Needs Translation/LSL/el Template:Needs Translation/LSL/fr Template:Needs Translation/LSL/he Template:Needs Translation/LSL/it Template:Needs Translation/LSL/ko Template:Needs Translation/LSL/nl Template:Needs Translation/LSL/hu Template:Needs Translation/LSL/no Template:Needs Translation/LSL/da Template:Needs Translation/LSL/sv Template:Needs Translation/LSL/tr Template:Needs Translation/LSL/pl Template:Needs Translation/LSL/pt Template:Needs Translation/LSL/ru Template:Needs Translation/LSL/th Template:Needs Translation/LSL/uk Template:Needs Translation/LSL/zh-Hans Template:Needs Translation/LSL/zh-Hant

/LSL

TransferLindenDollars

llTransferLindenDollars

Summary

Function: key llTransferLindenDollars( key destination, integer amount );

0.0	Forced Delay
	Energy

Transfer amount of L$ money from script owner to destination avatar.
Returns a key used in a matching transaction_result event for the success or failure of the transfer. If the transaction is successful, this key will show in the transaction history.

• key	destination	–	avatar UUID
• integer	amount	–	number of L$, must be greater than zero, (amount > 0)

To run this function the script must request the PERMISSION_DEBIT permission with llRequestPermissions and it must be granted by the owner. If you aren't going to use the return value or the resulting transaction_result event consider using llGiveMoney instead of this function.

Caveats

Permissions

Do not depend upon the auto-grant status of permissions. Always use the run_time_permissions event. If the script lacks the permission PERMISSION_DEBIT, the script will shout an error on DEBUG_CHANNEL and the operation fails (but the script continues to run). If PERMISSION_DEBIT is granted by anyone other than the owner, then when the function is called an error will be shouted on DEBUG_CHANNEL. Once the PERMISSION_DEBIT permission is granted there is no way to revoke it except from inside the script (for example, with a new llRequestPermissions call) or the script is reset or deleted.

• An object cannot pay another object.
• Objects deeded to groups cannot give money (the permission cannot be granted).
• Use is limited to 30 payments in a 30 second interval for all scripts owned by that resident on a region. Sustained overage will produce a script error and halt payments while the rate remains excessive. Historically, faster payments have failed intermittently.
• Once a script has the PERMISSION_DEBIT permission it can empty an account of L$.
  • Fraud & theft are both Linden Lab violations and crimes. Misuse this function and you risk being banned and legal action. In addition LL may freeze the accounts of anyone the money is transferred to and restore it to it's rightful owners. This may involve retrieving it from third party exchanges and accounts on those exchanges being frozen. The system is not designed to be friendly towards fraud.

Examples

<lsl>//A simple piggy bank, anyone can pay in money and anyone can click it to get money out.

integer AMOUNT = 10; //The amount of money to be given each time it is clicked. integer STASH = 50; //The amount of money the script has to give out by default.

list trks;

update() {

   if(STASH >= AMOUNT)
       llSetText("I have L$"+(string)STASH + " to give away!", <1,1,1>, 1);
   else
       llSetText("I have no L$ to give away :(", <1,1,1>, 1);

}

default {

   state_entry()
   {
       llRequestPermissions(llGetOwner(), PERMISSION_DEBIT );  
   }

   run_time_permissions (integer perm)
   {
       if(perm & PERMISSION_DEBIT)
       {
           state ready;     
       }
   }

}

state ready {

   state_entry()
   {
       update();
   }
   touch_start(integer num)
   {
       if(STASH >= AMOUNT)
       {
           trks += llTransferLindenDollars(llDetectedKey(0), AMOUNT);
           STASH -= AMOUNT;
           update();
       }
       else
       {
           llWhisper(0, "No more money to give away :(");
       }
   }
   money(key id, integer m)
   {
       STASH += m;
       update();
   }
   transaction_result(key id, integer success, string data)
   {
       integer i = llListFindList(trks, [id]);
       if(~i)//Is it one of our transactions?
       {//It was!
           trks = llDeleteSubList(trks, i, i);
           if(!success)//Did it fail?
           {//Put the money back in the bank.
               //TODO: Handle the different transaction failure modes returned in the data CSV.
               STASH += AMOUNT;
               llWhisper(0, "Sorry but the transaction failed for some reason :(");
           }
       }
   }

}</lsl>

Notes

• released on main server channel on 3-Dec-2011

See Also

Events

•	run_time_permissions	–	Permission receiving event
•	transaction_result
•	money

Functions

•	llGetPermissions	–	Get the permissions granted
•	llGetPermissionsKey	–	Get the agent who granted permissions
•	llRequestPermissions	–	Request permissions
•	llGiveMoney
•	llSetPayPrice

Articles

•

Script permissions

Deep Notes

Signature
function key llTransferLindenDollars( key destination, integer amount );