Listen

From Second Life Wiki
Jump to: navigation, search

Description

Event: listen( integer channel, string name, key id, string message ){ ; }

Triggered by chat, use llListen to enable and filter

• integer channel channel that the message appeared on.
• string name prim name or avatar Legacy Name
• key id group, avatar or prim UUID
• string message text spoken
Channel Constant Description
DEBUG_CHANNEL 0x7FFFFFFF Chat channel reserved for script debugging and error messages, broadcasts to all nearby users.
PUBLIC_CHANNEL 0x0 Chat channel that broadcasts to all nearby users. This channel is sometimes referred to as: open chat, local chat and public chat.

Caveats

  • On state change or script reset all listens are closed automatically.
  • When an object changes owner any listen registered with llGetOwner will not automatically update itself until the script is reset. The scripter can catch this scenario per the example below.
  • If a message satisfies the filters of multiple llListens registered by the script, only one event will be raised.
  • A prim cannot hear/listen to chat it generates.
  • The location of the listen is not at the listening prim's location but at the root prim's location. This is to deter people using child prims for spying over parcel boundaries. Chat generating functions on the other hand generate chat at the calling prim's location (and not at the root prim's location).
  • The above is not true for chat generated by avatars sitting on the same object as the listening prim.
All Issues ~ Search JIRA for related Bugs

Examples

KBcaution.png Important: Please make sure that you close open listeners where possible. You'll make the Second Life experience so much better when paying attention to details here.

Trivial example to listen to any chat from the object owner and respond once. To reduce lag and avoid spamming surrounding users, it is vastly preferable to listen on channels other than 0 and to trigger the listen event by chatting on an alternative channel such as '/5 hello'.

// says beep to owner the first time owner says something in main chat;
integer listen_handle;
 
default
{
    state_entry()
    {   //Registers the listen to the owner of the object at the moment of the call. This does not automatically update when the owner changes.
        // Change 0 to another positive number to listen for '/5 hello' style of chat.
        listen_handle = llListen(0, "", llGetOwner(), "");
    }
 
    listen( integer channel, string name, key id, string message )
    {
        llOwnerSay("beep");
        // Stop listening until script is reset
        llListenRemove(listen_handle);
    }
 
    changed(integer mask)
    {   //Triggered when the object containing this script changes owner.
        if(mask & CHANGED_OWNER)
        {
            llResetScript();   // This will ensure the script listens to the new owner, and doesn't continue listening to the creator.
        }
    }
}

See Also

Functions

•  llListen
•  llListenControl
•  llListenRemove
•  llDialog
•  llOwnerSay Sends chat to the owner only to avoid spamming the PUBLIC_CHANNEL
•  llWhisper Sends chat limited to 10 meters
•  llSay Sends chat limited to 20 meters
•  llShout Sends chat limited to 100 meters
•  llRegionSay Sends chat limited to region

Deep Notes

Issues

All Issues

~ Search JIRA for related Issues
   llTargetSay() - region-wide direct communication

Signature

event void listen( integer channel, string name, key id, string message );
This article wasn't helpful for you? Maybe the related article at the LSL Wiki is able to bring enlightenment.