LlSetText

Displays text over a prim with specific color and transparency (specified with alpha).

• A script calling llSetText cannot know if it is or is not changing the floating text, since there is no llGetText function.
• The floating text is a property of the prim and not the script, thus the text will remain if the script is deactivated or removed.
  • To remove floating text, one must assign an empty string with:

 
llSetText("", <1.0, 1.0, 1.0>, 1.0);
 

• Vertical whitespace is removed from the end of the text string, so if you want vertical whitespace put any character (like a space) on the last line:

 
llSetText("Monkeys\n\n\n\n\n", <1.0, 1.0, 1.0>, 1.0);//Bad
llSetText("Monkeys\n\n\n\n\n ", <1.0, 1.0, 1.0>, 1.0);//Good
 

Example of how llSetText could be included in default code to show object's name in green text:

 
default
 {
     state_entry()
     {
          llSay(0, "Hello, Avatar!");
          llSetText(llGetObjectName(), <0.0, 1.0, 0.0>, 1.0); // Display object's name in green
     }
 
     touch_start(integer total_number)
     {
          llSay(0, "Touched.");
     }
 }
 

By default the floating text will appear on a single line. However, the floating text can be spread over multiple lines by using a line break "\n" (read SplitLine in section 'See Also'). Example colors:

 
vector white = <1.0, 1.0, 1.0>;
vector red = <1.0, 0.0, 0.0>;
vector green = <0.0, 1.0, 0.0>;
vector blue = <0.0, 0.0, 1.0>;
vector grey = <0.5, 0.5, 0.5>;
vector black = <0.0, 0.0, 0.0>;
 

<1.0, 1.0, 1.0> represents the values for red, green, and blue. <1.0, 1.0, 1.0>, means "white" and <0.0, 0.0, 0.0> means "black":

 
llSetText("I am on", <1.0, 1.0, 1.0>, 1.0);
 

 
llSetText("I am off", <0.0, 0.0, 0.0>, 1.0);
 

The 1.0 is the alpha setting. 1.0 means fully opaque, and 0.0 would be completely transparent (invisible):

 
llSetText("alpha", <0.0, 1.0, 0.0>, 0.5);
 

Multiple lines:

 
llSetText("I am \n on two lines!", <0.0, 1.0, 0.0>, 1.0);
 

Drag this script out of inventory onto an object to erase its set text:

 
// http://wiki.secondlife.com/wiki/llSetText
default
{
    state_entry()
    {
        llSetText("", <0.0, 0.0, 0.0>, 0.0);
        llRemoveInventory(llGetScriptName());
    }
}
 

Articles