LlSetPrimitiveParams

Sets the prims parameters according to rules.

• list

rules

This is a very powerful & sharp function, each rule takes at least one parameter and has its own quirks. Each PRIM_* rule has its own dedicated article with specific information.

• This function causes the script to sleep for 0.2 seconds.
• If texture is missing from the prim's inventory and it is not a UUID or it is not a texture then an error is shouted on DEBUG_CHANNEL.
• If texture is a UUID then there are no new asset permissions consequences for the object.
  • The resulting object develops no new usage restrictions that might have occurred if the asset had been placed in the prims inventory.
• top_size and client values are different, the ranges do not line up, conversion is required. This simple equation can be used: answer = 1.0 - value. See top_size Explained for more information.
• If map is missing from the prim's inventory and it is not a UUID or it is not a texture then an error is shouted on DEBUG_CHANNEL.
• If map is a UUID then there are no new asset permissions consequences for the object.
  • The resulting object develops no new usage restrictions that might have occurred if the asset had been placed in the prims inventory.
• PRIM_POSITION caveats
  • Depending upon the situation position may need to be in local coordinates or region coordinates, See llSetPos#Specification for details.
  • The range the prim can move is limited if it is an unattached root prim. The distance is capped to 10m per PRIM_POSITION call. See WarpPos. This is a very special case. Do not rely on rule duplication of other flags - the results are undefined, and things will break in the future.
  • Moving a prim that an avatar is seated upon will not move the avatar; the sit target will not be updated.
    • To mimic updating of a sit-target, use UpdateSitTarget.
  • Moving avatars with PRIM_POSITION
    • Moving the prim the avatar sat upon does not move the avatar.
    • Moving an avatar does not move the prim they sat upon.
    • Sit-target coordinates do not easily map to prim coordinates, use UpdateSitTarget.
    • If position is greater than 54 meters away from the center, the repositioning will silently fail.
• PRIM_PHANTOM, PRIM_PHYSICS and PRIM_TEMP_ON_REZ applies to the entire object (linkset).
• Values may drift, become truncated or be range limited. Some limits are applied by the client during deserialization, others are applied by the simulator when the sim tries to store the values.
  • When testing vectors and rotations use llVecDist and llAngleBetween (respectfully) to perform fuzzy tests.
• If face is ALL_SIDES then the flag works on all sides.
• The flag silently fails if its face value indicates a face that does not exist.
• The sim will clamp attributes before storing them.
• The client will clamp attributes before rendering.
• Scripts written before September 2004 that use PRIM_TYPE depend on PRIM_TYPE to have the value 1; if these scripts are recompiled, the new value of PRIM_TYPE will be used causing errors at runtime.
  • To fix this replace the PRIM_TYPE flag with the value 1 or updated to the newer PRIM_TYPE syntax.
• PRIM_ROTATION is bugged in child prims, see deep notes for issue discussion and fix.

Important Issues

~ Search JIRA for related Bugs

		SVC-914	[c]		CHANGED_TEXTURE is not triggered when texture is changed via script
		SVC-93	[c]		llSetRot and llSetPrimitiveParams (using PRIM_ROTATION) incorrectly implemented for child prims.

 
// To color all sides of a prim black, except side 3 white
llSetPrimitiveParams([PRIM_COLOR, ALL_SIDES, <0.0,0.0,0.0>, 1.0]);
llSetPrimitiveParams([PRIM_COLOR, 3, <1.0,1.0,1.0>, 1.0]);
 
// To render on side 3 
// the picture with the UUID... 
// and the repeats per face as vector, 
// the texture offset as second vector, 
// and the texture rotation as float
llSetPrimitiveParams([PRIM_TEXTURE, 3, "4d304955-2b01-c6c6-f545-c1ae1e618288",
                          <1.0,1.0,0.0>, <0.0,0.0,0.0>, 0.0]);
 
// To set the prim "Full Bright" on sides 3
llSetPrimitiveParams([PRIM_FULLBRIGHT,3,TRUE]);
 
// And to make it all in one breath,
llSetPrimitiveParams([PRIM_COLOR, ALL_SIDES, <0.0,0.0,0.0>, 1.0,
                      PRIM_COLOR, 3, <1.0,1.0,1.0>, 1.0,
                      PRIM_TEXTURE, 3, "4d304955-2b01-c6c6-f545-c1ae1e618288",
                          <1.0,1.0,0.0>, <0.0,0.0,0.0>, 0.0,
                      PRIM_FULLBRIGHT, 3, TRUE]);
 
//And If you want to place it above you bed, to make you sleep well, and the coords
// of that place are for example <x, y, z>
llSetPrimitiveParams([PRIM_COLOR, ALL_SIDES, <0.0,0.0,0.0>, 1.0, 
                      PRIM_COLOR, 3, <1.0,1.0,1.0>, 1.0,
                      PRIM_TEXTURE, 3, "4d304955-2b01-c6c6-f545-c1ae1e618288",
                          <1.0,1.0,0.0>, <0.0,0.0,0.0>,0.0,
                      PRIM_FULLBRIGHT, 3, TRUE, 
                      PRIM_POSITION, <x, y, z>]);
 
//You can set the texture of several sides at once, with no time penalty,
//just by repeating the param for that:
llSetPrimitiveParams([
        PRIM_TEXTURE, 3, "4d304955-2b01-c6c6-f545-c1ae1e618288",
            <1.0,1.0,0.0>, <0.0,0.0,0.0>, 0.0,
        PRIM_TEXTURE, 4, "4d304955-2b01-c6c6-f545-c1ae1e618288",
            <1.0,1.0,0.0>, <0.0,0.0,0.0>, 0.0
    ]);
 

Top-size (taper)

default
{
    state_entry()
    {
        vector XYZ = llGetScale();
        float X = XYZ.x;
        float Y = XYZ.y;     
        llSetPrimitiveParams([PRIM_SIZE, <X,Y,0.1>, // keep the prim thin
                              PRIM_TYPE, PRIM_TYPE_BOX, 0, <0.0,1.0,0.0>, 0.0, ZERO_VECTOR, 
                              <1.0 - (0.4 / X), 1.0 - (0.4 / Y), 0.0>,
                              ZERO_VECTOR]); //We use the equation "answer = 1 - desired_taper"
        //The proportions of the top-size (taper) will be maintained (as close as possible)
        // whenever the prim is resized. The proportion above will produce a reasonably
        // pleasing picture frame kinda thing.
    }
    changed(integer change)
    {
        if(change & CHANGED_SCALE)
        {
            llResetScript();
        }
    }
}

The old PRIM_TYPE interface (labeled PRIM_TYPE_LEGACY) while technically retired can still be used.

Functions

•	llGetPrimitiveParams	–	Get many primitive parameters
•	llSetLinkPrimitiveParams	–	Set parameters on other prims in linkset
•	llSetAlpha	–	Simpler way to set alpha (transparency)
•	llSetTexture	–	Simpler way to set texture
•	llSetColor	–	Simpler way to set color
•	llSetScale	–	Simpler way to set scale
•	llSetStatus	–	Simpler way to set physics and phantom

Articles

•	Color in LSL
•	Translucent Color

Issues

~ Search JIRA for related Issues

		SVC-914	[c]		CHANGED_TEXTURE is not triggered when texture is changed via script
		SVC-93	[c]		llSetRot and llSetPrimitiveParams (using PRIM_ROTATION) incorrectly implemented for child prims.