LlSetLinkTexture

If a prim exists in the link set at link, set texture on face of that prim.

If face is ALL_SIDES then the function works on all sides.

Important Issues

		SVC-1500	[A, C]		llSetLinkTexture fails and reports an error on textures created by someone else without full permissions
		SVC-3199	[A, C]		llSetLinkTexture(LINK_THIS, foo, bar) does not work for non-full-perm textures.

Cover a link set in the texture "bark" (from the library)

default
{
    touch_start(integer detected)
    {
        llSetLinkTexture(LINK_SET, "66bf4030-04f9-a808-43ab-b48b6aeb6456", ALL_SIDES);
    }
}

SetLinkTextureFast

This function doesn't have the 0.2 second delay. It's not very fast anyway though, but faster than llSetLinkTexture.

SetLinkTextureFast(integer link, string texture, integer face)
{
    // Obtain the current texture parameters and replace the texture only.
    // If we are going to apply the texture to ALL_SIDES, we need
    // to adjust the returned parameters in a loop, so that each face
    // keeps its current repeats, offsets and rotation.
    list Params = llGetLinkPrimitiveParams(link, [PRIM_TEXTURE, face]);
    integer idx;
    face *= face > 0; // Make it zero if it was ALL_SIDES
    // This part is tricky. The list returned by llGLPP has a 4 element stride
    // (texture, repeats, offsets, angle). But as we modify it, we add two
    // elements to each, so the completed part of the list has 6 elements per
    // stride.
    integer NumSides = llGetListLength(Params) / 4; // At this point, 4 elements per stride
    for (idx = 0; idx < NumSides; ++idx)
    {
        // The part we've completed has 6 elements per stride, thus the *6.
        Params = llListReplaceList(Params, [PRIM_TEXTURE, face++, texture], idx*6, idx*6);
    }
    llSetLinkPrimitiveParamsFast(link, Params);
}

Link Numbers

Each prim that makes up an object has an address, a link number. To access a specific prim in the object, the prim's link number must be known. In addition to prims having link numbers, avatars seated upon the object do as well.

• If an object consists of only one prim, and there are no avatars seated upon it, the (root) prim's link number is zero.
• However, if the object is made up of multiple prims or there is an avatar seated upon the object, the root prim's link number is one.

When an avatar sits on an object, it is added to the end of the link set and will have the largest link number. In addition to this, while an avatar is seated upon an object, the object is unable to link or unlink prims without unseating the avatars first.

Counting Prims & Avatars

There are two functions of interest when trying to find the number of prims and avatars on an object.

• llGetNumberOfPrims() - Returns the number of prims and seated avatars.
• llGetObjectPrimCount(llGetKey()) - Returns only the number of prims in the object but will return zero for attachments.

integer GetPrimCount() { //always returns only the number of prims
    if(llGetAttached())//Is it attached?
        return llGetNumberOfPrims();//returns avatars and prims but attachments can't be sat on.
    return llGetObjectPrimCount(llGetKey());//returns only prims but won't work on attachments.
}

Functions

All Issues

		SVC-1500	[A, C]		llSetLinkTexture fails and reports an error on textures created by someone else without full permissions
		SVC-3199	[A, C]		llSetLinkTexture(LINK_THIS, foo, bar) does not work for non-full-perm textures.
		SVC-914	[A, C]		CHANGED_TEXTURE is not triggered when texture is changed via script

Footnotes

function void llSetLinkTexture( integer link, string texture, integer face );