LlGetObjectDetails

Returns a list of the details for id, specifically those requested in params.

An empty list if id is not found. OBJECT_UNKNOWN_DETAIL is returned when passed an invalid integer parameter.

Avatar detection range for SL Server 1.34

id Parameter

id holds the UUID of the avatar or prim this function is going to get the details of.

If id is not found in the region, adjacent regions are searched for avatars which match id. An avatar is only considered to have been found if it is inside the region, or within a 34 meter zone outside the region boundaries (see diagram). A single valid result may be returned after the avatar leaves this zone.

params Parameter

The params list is used to indicate which object attributes of interest. The order they are supplied in determines the order of the corresponding return values in the return list.

Important Issues

SVC-7592

[A, C]

[Won't Fix] OBJECT_RUNNING_SCRIPT_COUNT includes the crashed scripts in the count of running scripts.

default
{
    collision_start(integer i)
    {
        list a = llGetObjectDetails(llDetectedKey(0), ([OBJECT_NAME, 
                    OBJECT_DESC, OBJECT_POS, OBJECT_ROT, OBJECT_VELOCITY,
                    OBJECT_OWNER, OBJECT_GROUP, OBJECT_CREATOR]));
        llWhisper(0,"UUID: "         + (string)llDetectedKey(0) +
                  "\nName: \""       + llList2String(a,0) + "\"" +
                  "\nDescription: \"" + llList2String(a,1) + "\"" +
                  "\nPosition: "     + llList2String(a,2) +
                  "\nRotation: "     + llList2String(a,3) +
                  "\nVelocity: "     + llList2String(a,4) +
                  "\nOwner: "        + llList2String(a,5) +
                  "\nGroup: "        + llList2String(a,6) +
                  "\nCreator: "      + llList2String(a,7));
    }
}

// group join inviter
// gets the name of the object's active group from the online group profile
 
key groupNameRequestId;
key groupKey;
string groupName;
 
init()
{
    // WARNING:
    // different prims can have different active groups!!!
 
    // get the key of the root prim's group
    groupKey = llList2Key(llGetObjectDetails(llGetLinkKey(LINK_ROOT), [OBJECT_GROUP]), 0);
 
    // request the name of the root prim's group
    groupNameRequestId = llHTTPRequest("http://world.secondlife.com/group/" + (string)groupKey, [], "");
}
 
default
{
    state_entry()
    {
        init();
    }
 
    touch_start(integer num_detected)
    {
        if (groupKey == NULL_KEY || groupName == "")
            return;
 
        key id = llDetectedKey(0);
        llInstantMessage(id,
            "Click the link to join the group '" + groupName + "'\n"
            + "secondlife:///app/group/" + (string)groupKey + "/about");
    }
 
    http_response(key request_id, integer status, list metadata, string body)
    {
        if (request_id != groupNameRequestId)
            return;
 
        list args = llParseString2List(body, ["title"], []);
        groupName = llList2String(llParseString2List(llList2String(args, 1), [">", "<", "/"], []), 0);
    }
}

// aim & shoot
default
{   state_entry()
    {   llRequestPermissions(llGetOwner(), PERMISSION_TAKE_CONTROLS);
    }
    control(key id, integer pressed, integer change) 
    {   if(change & pressed & CONTROL_ML_LBUTTON)
            llSensor("", "", AGENT|PASSIVE|ACTIVE, 96.0, PI/16.0);
    }
    run_time_permissions(integer perm)
    {   if(perm&PERMISSION_TAKE_CONTROLS)
            llTakeControls(0x7FFFFFFF, TRUE, TRUE); 
    }
    sensor(integer n)
    {   key uuid=llDetectedKey(0);
        list a = llGetObjectDetails(uuid, ([
            OBJECT_NAME, OBJECT_DESC, OBJECT_POS, OBJECT_ROT,
            OBJECT_VELOCITY,OBJECT_OWNER, OBJECT_GROUP, OBJECT_CREATOR]));
        llOwnerSay("UUID: " + (string)uuid +
            "\nName: \"" + llList2String(a,0)+ "\"" +
            "\nDecription: \"" + llList2String(a,1) + "\"" +
            "\nPosition: " + llList2String(a,2) +
            "\nRotation: " + llList2String(a,3) +
            "\nVelocity: " + llList2String(a,4) +
            "\nOwner: " + llList2String(a,5) +
            "\nGroup: " + llList2String(a,6) +
            "\nCreator: " + llList2String(a,7)
        );
    }
}

// Object Script Time
default
{
    touch_start(integer num_detected)
    {
        llOwnerSay(llGetObjectName()+" Script Time: "+llList2String(llGetObjectDetails(llGetKey(), [OBJECT_SCRIPT_TIME]), 0));
    }
}

See Link/Get for some link related helper functions. Also see llGetLinkPrimitiveParams if you need to get the position and rotation of a linked prim.

integer isLindenTreeOrGrass(key id){
    //Check if it's an OPT_OTHER and not an attachment, which makes it a Linden tree or grass!
    list out = llGetObjectDetails(id, [OBJECT_PATHFINDING_TYPE, OBJECT_ATTACHED_POINT]);
    return (llList2Integer(out, 0) == OPT_OTHER) && !llList2Integer(out, 1);
}

Functions

Articles

History

All Issues

		SCR-87	[A, C]		OBJECT_DISPLAY_NAME and OBJECT_USERNAME to llGetObjectDetails()
		SVC-7592	[A, C]		[Won't Fix] OBJECT_RUNNING_SCRIPT_COUNT includes the crashed scripts in the count of running scripts.

function list llGetObjectDetails( key id, list params );
integer OBJECT_SERVER_COST = 14;//Gets the server cost of the object.
integer OBJECT_STREAMING_COST = 15;//Gets the streaming (download) cost of the object.
integer OBJECT_PHYSICS_COST = 16;//Gets the physics cost of the object.