LlSetPrimitiveParams/ja

/ja

/LSL

rulesに沿ってプリムのパラメータを設定します。

• list

rules

これはとても強力で切れ味のよい関数で、それぞれのルールは 1 個以上のパラメタを受け入れ、奇癖もあります。それぞれの PRIM_* ルールには仕様が載っている専用の記事があります。

• この関数は 0.2 秒間、スクリプトを停止します。
• texture がプリムの中で見つからない場合、かつこれが UUID でない場合、またはこれがtextureでない場合、エラーが DEBUG_CHANNEL 上で叫ばれます。
• texture が UUID である場合、オブジェクト自体に新たな アセット権限 が発生するようなことはありません。
  • アセットをプリムのインベントリの中に置いた場合、これまで発生していた使用制限は新しいオブジェクトで新たに作成されません。
• ストレージ媒体として フローティングテキスト の機能が使えると思わないでください。これは不完全ですし、安全なものでもありません。
  • フローティングテキストはサーバの更新時に変更になったことが過去にあり、その際に既に設定されている内容は消去されていました。将来も変更が発生する可能性があります。
  • 「不可視」^[1] のフローティングテキストもクライアントに送信されます。
    • 不可視にしているテキストを表示することのできるクライアントを持っている人が見れてしまう可能性があります。
    • テキストが含まれている通信パケットが盗聴され、テキストが読まれる可能性があります。
• top_size とクライアントの値は異なります。範囲は一致しておらず、変換が必要です。シンプルな計算式は、結果 = 1.0 - value です。詳細は top_size Explained をご覧ください。
• map がプリムの中で見つからない場合、かつこれが UUID でない場合、またはこれがtextureでない場合、エラーが DEBUG_CHANNEL 上で叫ばれます。
• map が UUID である場合、オブジェクト自体に新たな アセット権限 が発生するようなことはありません。
  • アセットをプリムのインベントリの中に置いた場合、これまで発生していた使用制限は新しいオブジェクトで新たに作成されません。
• PRIM_POSITION caveats
  • 状況によって position は ローカル座標 か リージョン座標 のどちらかを指定する必要があります。詳細は llSetPosの仕様 を参照してください。
  • アタッチされていないルートプリムの場合、プリムが動ける範囲は限られています。PRIM_POSITION 1 コールあたり 10m に制限されています。WarpPos を参照してください。これは非常に特殊なケースです。 Do not rely on rule duplication of other flags - 結果は不定で、将来 きっと 壊れます。
  • PRIM_POSITION で アバター を動かすときは、
    • アバターが座っているプリムを動かしてもアバターは動きません。
    • アバターを動かしても、アバターが座っているプリムは動きません。
    • 座っている位置の座標はプリムの座標に素直に連動しません。SitTargetを更新 を使ってください。
    • position が中心から 54 メートルを超えると、エラーを出さずに失敗します。
• PRIM_PHANTOM, PRIM_PHYSICS と PRIM_TEMP_ON_REZ はオブジェクト全体（リンクセット）に適用されます。
• 値はズレたり、切り捨てられたり、上限があったりすることもあります。描画の前にデシリアライゼーションの過程でクライアントがかける制限もあれば、SIM が値を格納する前にかける制限もあります。
  • vector と rotation をテストする時には、(それぞれ) llVecDist と llAngleBetween を使ってファジングを行いましょう。
• face が ALL_SIDES であれば flag は全ての面に作用します。
• face が存在しない面を指している場合、 flag はエラーを出さずに復帰します。
• スクリプトは、2004年9月以前のものはPRIM_TYPEが1の値を示すかどうかで書かれていました。これらのスクリプトが再コンパイルされる場合、新しい値のPRIM_TYPEはコンパイルエラーを起こすでしょう。
  • 修正するには、これをPRIM_TYPEフラグと1の値に置き換えるか、新しいPRIM_TYPE構文にアップデートします。
• PRIM_ROTATION は子プリムでバグがあります。議論と修正については特記事項を参照してください。
• この関数は与えられたデータの型が間違っていたらエラーを返します。これは、ユーザ入力やノートカードでデータを渡すときに問題になってきます。改善するには、この List Cast 関数を参照してください。 list_cast

重要事項

~ JIRA で関連バグを検索

		SVC-914	[C]		CHANGED_TEXTURE is not triggered when texture is changed via script
		SVC-93	[C]		llSetRot and llSetPrimitiveParams (using PRIM_ROTATION) incorrectly implemented for child prims.

// プリムの全ての面を黒にします。面番号 3 の面だけは白くします。
llSetPrimitiveParams([PRIM_COLOR, ALL_SIDES, <0.0,0.0,0.0>, 1.0]);
llSetPrimitiveParams([PRIM_COLOR, 3, <1.0,1.0,1.0>, 1.0]);
 
// 面番号 3 の面を描画します。
// 画像を UUID で指定して... 
// 面ごとに繰り返す数をベクトルに指定して、
// テクスチャのずれを 2 番目のベクトルに指定して
// テクスチャの回転を浮動小数点数で指定します。
llSetPrimitiveParams([PRIM_TEXTURE, 3, "4d304955-2b01-c6c6-f545-c1ae1e618288", <1.0,1.0,0.0>, <0.0,0.0,0.0>, 0.0]);
 
// 面番号 3 を「フルブライト」にします。
llSetPrimitiveParams([PRIM_FULLBRIGHT,3,TRUE]);
 
// そしてこれらを一気にやる方法です。
llSetPrimitiveParams([PRIM_COLOR, ALL_SIDES, <0.0,0.0,0.0>, 1.0,
                      PRIM_COLOR, 3, <1.0,1.0,1.0>, 1.0,
                      PRIM_TEXTURE, 3, "4d304955-2b01-c6c6-f545-c1ae1e618288", <1.0,1.0,0.0>, <0.0,0.0,0.0>, 0.0,
                      PRIM_FULLBRIGHT, 3, TRUE]);
 
//さらにこれをベッドの上に置いて、よく眠れるようにしたいとき、その座標が例えば <x, y, z> なら
llSetPrimitiveParams([PRIM_COLOR, ALL_SIDES, <0.0,0.0,0.0>, 1.0, 
                      PRIM_COLOR, 3, <1.0,1.0,1.0>, 1.0,
                      PRIM_TEXTURE, 3, "4d304955-2b01-c6c6-f545-c1ae1e618288", <1.0,1.0,0.0>, <0.0,0.0,0.0>,0.0,
                      PRIM_FULLBRIGHT, 3, TRUE, 
                      PRIM_POSITION, <x, y, z>]);
 
//複数の面に時間のペナルティなしでテクスチャを一度に設定することができます。
//パラメタを設定するぶん繰り返すだけです。
llSetPrimitiveParams([
        PRIM_TEXTURE, 3, "4d304955-2b01-c6c6-f545-c1ae1e618288",
            <1.0,1.0,0.0>, <0.0,0.0,0.0>, 0.0,
        PRIM_TEXTURE, 4, "4d304955-2b01-c6c6-f545-c1ae1e618288",
            <1.0,1.0,0.0>, <0.0,0.0,0.0>, 0.0
    ]);

Top-size (テーパー)

default
{
    state_entry()
    {
        vector XYZ = llGetScale();
        float X = XYZ.x;
        float Y = XYZ.y;     
        llSetPrimitiveParams([PRIM_SIZE, <X,Y,0.1>, // プリムを薄くしておきます
                              PRIM_TYPE, PRIM_TYPE_BOX, 0, <0.0,1.0,0.0>, 0.0, ZERO_VECTOR, 
                              <1.0 - (0.4 / X), 1.0 - (0.4 / Y), 0.0>,
                              ZERO_VECTOR]); //方程式「解 = 1 - 希望するテーパー」を使用します
        //プリムの大きさが変更になっても top-size (テーパー) の比が維持される (できるだけ近づく) ようになります。
        //上の比率はでいい感じの額縁のようなものを作ることができます。
    }
    changed(integer change)
    {
        if(change & CHANGED_SCALE)
        {
            llResetScript();
        }
    }
}

(PRIM_TYPE_LEGACYと名づけられた)古いPRIM_TYPEのインターフェイスは廃れた技術として使用が廃止されました。

関数

•	llGetPrimitiveParams	–	多くのプリムのパラメータを取得します
•	llSetLinkPrimitiveParams
•	llSetAlpha	–	アルファ(透明度)を設定する簡単な方法です
•	llSetTexture	–	テクスチャを設定する簡単な方法です
•	llSetColor	–	色を設定する簡単な方法です
•	llSetScale	–	大きさを設定する簡単な方法です
•	llSetStatus	–	物理属性とファントムを設定する簡単な方法です

記事

•	各種制限	–	SL の制限と制約
•	LSL での色
•	透明度
•	LSL での色
•	透明度

記事

~ JIRA で関連記事を検索

		SVC-914	[C]		CHANGED_TEXTURE is not triggered when texture is changed via script
		SVC-93	[C]		llSetRot and llSetPrimitiveParams (using PRIM_ROTATION) incorrectly implemented for child prims.

脚注